ورود به حساب ثبت نام جدید فراموشی کلمه عبور
برای ورود به حساب کاربری خود، نام کاربری و کلمه عبورتان را در زیر وارد کرده و روی «ورود به سایت» کلیک کنید.





اگر فرم ثبت نام برای شما نمایش داده نمی‌شود، اینجا را کلیک کنید.









اگر فرم بازیابی کلمه عبور برای شما نمایش داده نمی‌شود، اینجا را کلیک کنید.





کاربران برچسب زده شده

نمایش نتایج: از 1 به 3 از 3
  1. #1
    2009/04/17
    83
    1

    اضافه کردن قطعه در کتابخانه فقط با داشتن مدل SPICE

    با سلام
    من مدل Spice قطعه HCPL-316J را دانلود کردم اما نمی دونم چطور می شه به کتابخانه وارد کرد.
    ساخت قطعه رو می دونم اما مدل SPICE چی می شه؟

    با تشکر
    * Copyright 2009 Avago Technologies Limited. All Right Reserved
    *
    * HCPL-316J Spice Macromodel
    *
    * Rev 2.1 10/04/2010
    * - UVLO reference to VE
    * - Porting from HSPICE to LT SPice
    * - SPICE Model is verified by LT Spice at Ta=25^C.
    * - Macro model performance matches the typical datasheet specifications
    * + Tplh=320ns, Tphl=290ns
    * + Tdesat(low)=0.25us, Tdesat(10%)=2us, Tdesat(90%)=0.15us,
    * + Tdesat(Fault)=2.3us, Treset(fault)=7.5us
    * + output low drive: Iol=2A@Vo=2.5V
    * + ouput high drive: Ioh=2A@Voh=Vcc2-4.3V
    * + Input Voltage Threshold: Vin_th = 1.5, note Vinp and Reset should tie together for proper simulation
    * - Worst case performance are not modeled.
    *
    * Macromodels provided by Avago Technologies are not warranted
    * as fully representing all of the specification and operating
    * characteristics of the product.
    *
    * Macromodels are useful for evaluating product performance but they
    * cannot model exact device performance under all condition, nor are
    * they intented to replace breadboarding for final verification.
    *
    ************************************************** ********************
    * block symbol definitions
    .subckt hcpl-316j VINP VINN VCC1 GND1 RESET_B FAULT_B VLED1 GND1 VEE2 VEE2 VOUT VC VCC2 DESAT VLED2 VE
    XX1 N014 VLED1 VCC1 GND1 ledbuf
    XX3 N008 VINP N015 N014 GND1 VCC1 and3
    XX4 VLED1 GND1 VE N005 DVDD opto
    XX5 N017 N015 GND1 VCC1 inv
    XX6 N032 N027 GND1 VCC1 inv
    XX8 VLED2 VE GND1 N031 VCC1 opto
    XX9 N025 N027 N024 GND1 VCC1 rs
    M1 FAULT_B N017 GND1 GND1 LDMOS W=10u L=0.6u
    R1 N031 N025 1k
    C1 N025 GND1 500p
    XX7 DVDD N003 DESAT VE N004 comparator
    XX10 N001 N004 N002 VE DVDD or2
    XX11 N002 N005 N001 VE DVDD and2
    XX12 N001 N007 N006 VE DVDD or2
    XX14 N005 N007 VE DVDD inv
    XX15 N001 N023 VE DVDD inv
    XX16 N029 N026 VE DVDD inv
    XX17 N013 N005 N023 N026 N020 VE DVDD and4
    XX18 N020 N022 VE DVDD inv
    M2 DESAT N006 VE VE NMOS1 W=3u L=2u
    Q1 VCC2 N018 N019 0 NPNMOD1 40
    Q2 VCC2 N016 N018 0 NPNMOD1 5
    Q3 VCC2 N012 N016 0 NPNMOD1 1
    M3 VOUT N036 VEE2 VEE2 LDMOS W=1000u L=1.0u
    M4 VOUT N035 VEE2 VEE2 LDMOS W=24u L=1.0u
    M5 N011 N011 VCC2 VCC2 PMOS1 W=10u L=0.6u
    M6 N012 N011 VCC2 VCC2 PMOS1 W=100u L=0.6u
    I1 N011 VEE2 200u
    D1 VOUT N018 D
    D2 N018 N016 D
    D3 N016 N012 D
    M7 N012 N034 VEE2 VEE2 LDMOS W=10u L=1.0u
    E1 N035 VEE2 N001 VE 2
    E2 N034 VEE2 N021 VE 2
    E3 N036 VEE2 N029 VE 2
    XX19 N022 N028 N030 N029 VE DVDD and3
    XX20 N009 N039 N001 N028 VE DVDD or3
    XX21 N038 N030 VE DVDD inv
    XX22 N005 N039 VE DVDD inv
    XX23 DVDD VCC2 N010 VE N009 comparator
    XX24 N009 N013 VE DVDD inv
    XX25 N037 N001 N038 VE DVDD and2
    XX26 N020 N021 VE DVDD inv
    V3 N003 VE 7
    I2 VC DESAT 250u
    XX27 N001 VLED2 DVDD VE ledbuf
    R3 N019 VOUT 0.1
    R4 N010 VE 12k
    I3 VE N010 1.2m
    R5 N010 N009 40k
    D4 VE VE Z5V
    R7 5V VC 10k
    E5 DVDD VE 5V VE 1
    XX13 DVDD N033 VOUT VE N037 comparator
    V1 N033 VEE2 2
    C3 N021 VE 100p
    C4 N029 VE 100p
    R6 N017 N024 1k
    C5 N017 GND1 600p
    R8 RESET_B N032 5k
    C6 N032 GND1 2n
    XX2 VINN N008 GND1 VCC1 inv_ttl
    V2 5V VE 5
    .MODEL LDMOS NMOS LEVEL=3 L=1.0000E-6 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=1.55 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=20E-6
    + RS=10.000E-3 RD=10.000E-3 VTO=-9.54E-1 RDS=1.0000E6
    + TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0 RG=5
    + RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6
    + RS=10.000E-3 RD=10.000E-3 VTO=7.55E-1 RDS=1.0000E6
    + TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10 CBD=1.0000E-12
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .MODEL NPNMOD1 NPN IS=2.06E-16 VAF=92.2 NF=.998
    + BF=297 ISE=5.990E-17
    + NE=1.308 IKF=9.568E-3 RE=20 RC=36.19 RB=323.1 IRB=30.88U RBM=66.12
    + BR=892.9M ISC=8.844E-16 NR=1.005 VAR=2.872 NC=1.1 IKR=5.201E-3
    + CJE=.23P MJE=.7278 VJE=.9627 CJC=.157P MJC=.3924 VJC=.580
    + CJS=.505P MJS=.1387 VJS=.3757 FC=.5 XTB=1.52 TR=0.2E-7
    + XCJC=.35 TF=.116N PTF=46.26 XTF=213.8 VTF=.568 ITF=113.2E-3
    .MODEL Z5V D IS=1E-4 N=1.5 XTI=3 EG=1.52 BV=5 IBV=100u
    .ends hcpl-316j

    .subckt ledbuf A Y VDD VSS
    M1 N002 A VSS VSS NMOS1 W=2u L=0.6u
    M2 N002 A VDD VDD PMOS1 W=5u L=0.6u
    M3 Y N002 VSS VSS NMOS1 W=20u L=0.6u
    I1 N001 VSS 0.2m
    M4 Y N001 VDD VDD PMOS1 W=500u L=0.6u
    M5 N001 N001 VDD VDD PMOS1 W=10u L=0.6u
    M6 N001 A VDD VDD PMOS1 W=5u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends ledbuf

    .subckt and3 A B C Y VSS VDD
    M1 N001 A N002 N002 NMOS1 W=2u L=0.6u
    M2 N001 A VDD VDD PMOS1 W=5u L=0.6u
    M3 N002 B N003 N003 NMOS1 W=50u L=0.6u
    M4 N003 C VSS VSS NMOS1 W=2u L=0.6u
    M5 N001 B VDD VDD PMOS1 W=2u L=0.6u
    M6 N001 C VDD VDD PMOS1 W=5u L=0.6u
    M7 Y N001 VDD VDD PMOS1 W=5u L=0.6u
    M8 Y N001 VSS VSS NMOS1 W=2u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends and3

    .subckt opto an ca gnd2 vout vcc2
    E1 N008 N009 N006 N007 {CTR}
    XX1 an ca N007 N006 vbu
    XX2 N008 N009 N002 N003 pdnoc
    E2 N001 gnd2 vcc2 gnd2 1
    I1 N002 N003 2u
    XX3 N002 N002 gnd2 N001 inv
    XX4 N004 N005 gnd2 vcc2 inv
    XX6 N005 vout gnd2 vcc2 inv
    XX7 N003 N004 N002 tia
    C1 N005 gnd2 2p
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=20E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .param CTR=0.08
    .ends opto

    .subckt inv A Y VSS VDD
    M1 Y A VSS VSS NMOS1 W=2u L=0.6u
    M2 Y A VDD VDD PMOS1 W=5u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends inv

    .subckt rs S R Q VSS VDD
    M1 N003 Q VSS VSS NMOS1 W=2u L=0.6u
    M2 N002 S VDD VDD PMOS1 W=5u L=0.6u
    M3 Q N003 VSS VSS NMOS1 W=2u L=0.6u
    M4 N003 S VSS VSS NMOS1 W=2u L=0.6u
    M5 N003 Q N002 N002 PMOS1 W=5u L=0.6u
    M6 Q N003 N001 N001 PMOS1 W=5u L=0.6u
    M7 N001 R VDD VDD PMOS1 W=5u L=0.6u
    M8 Q R VSS VSS NMOS1 W=2u L=0.6u
    R1 Q VSS 100k
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends rs

    .subckt comparator VDD VINN VINP VSS VO
    G1 N005 N001 VINP VINN 0.1
    D1 N001 N003 D
    D2 N003 N005 D
    D3 N004 N001 D
    D4 N005 N004 D
    XX1 N001 N002 VSS VDD inv
    XX2 N002 VO VSS VDD inv
    XX3 N005 N005 VSS VDD inv
    .ends comparator

    .subckt or2 A B Y VSS VDD
    M1 N001 B VSS VSS NMOS1 W=50u L=0.6u
    M2 N002 A VDD VDD PMOS1 W=100u L=0.6u
    M3 N001 A VSS VSS NMOS1 W=2u L=0.6u
    M5 N001 B N002 N002 PMOS1 W=5u L=0.6u
    M4 Y N001 VDD VDD PMOS1 W=5u L=0.6u
    M6 Y N001 VSS VSS NMOS1 W=2u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends or2

    .subckt and2 A B Y VSS VDD
    M1 N001 A N002 N002 NMOS1 W=2u L=0.6u
    M2 N001 A VDD VDD PMOS1 W=5u L=0.6u
    M3 N002 B VSS VSS NMOS1 W=2u L=0.6u
    M5 N001 B VDD VDD PMOS1 W=5u L=0.6u
    M4 Y N001 VDD VDD PMOS1 W=5u L=0.6u
    M6 Y N001 VSS VSS NMOS1 W=2u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends and2

    .subckt and4 A B C D Y VSS VDD
    M1 N001 A N002 N002 NMOS1 W=2u L=0.6u
    M2 N001 A VDD VDD PMOS1 W=5u L=0.6u
    M3 N002 B N003 N003 NMOS1 W=2u L=0.6u
    M4 N003 C N004 N004 NMOS1 W=2u L=0.6u
    M5 N001 B VDD VDD PMOS1 W=5u L=0.6u
    M6 N001 C VDD VDD PMOS1 W=5u L=0.6u
    M7 N001 D VDD VDD PMOS1 W=5u L=0.6u
    M8 N004 D VSS VSS NMOS1 W=2u L=0.6u
    M9 Y N001 VDD VDD PMOS1 W=5u L=0.6u
    M10 Y N001 VSS VSS NMOS1 W=2u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends and4

    .subckt or3 A B C Y VSS VDD
    M1 N002 B VSS VSS NMOS1 W=2u L=0.6u
    M2 N003 A N001 N001 PMOS1 W=5u L=0.6u
    M3 N002 A VSS VSS NMOS1 W=2u L=0.6u
    M5 N002 B N003 N003 PMOS1 W=5u L=0.6u
    M4 Y N002 VDD VDD PMOS1 W=5u L=0.6u
    M6 Y N002 VSS VSS NMOS1 W=2u L=0.6u
    M7 N001 C VDD VDD PMOS1 W=5u L=0.6u
    M8 N002 C VSS VSS NMOS1 W=2u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends or3

    .subckt inv_ttl A Y VSS VDD
    M1 Y A VSS VSS NMOS1 W=50u L=0.6u
    M2 Y A VDD VDD PMOS1 W=5u L=0.6u
    .MODEL PMOS1 PMOS LEVEL=3 L=5.5000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=-9.54E-1 RDS=1.0000E6 TOX=1.24E-8 CGSO=2.01E-10 CGDO=2.01E-10 CBD=0
    + RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=215
    .MODEL NMOS1 NMOS LEVEL=3 L=5.0000E-7 W=2E-6 RS=10.000E-3 RD=10.000E-3
    + VTO=7.55E-1 RDS=1.0000E6 TOX=1.25E-8 CGSO=1.83E-10 CGDO=1.83E-10
    + CBD=1.0000E-12 RG=5 RB=1.0000E-3 GAMMA=0 KAPPA=0 UO=400
    .ends inv_ttl

    .subckt vbu AN CA LOPN LOPP
    RSERIES AN 5 5
    DELECT 5 CA VBUNOR
    ELED 6 LOPN 5 CA 1
    DOPTIC 6 8 VBUNORC
    FPHOTO LOPN 3 VSENSE 1
    VSENSE 8 LOPN 0
    RL 3 LOPN 0.1
    EOUT LOPP LOPN 3 LOPN 60
    VSIM LOPN CA 0
    Rnl 6 N001 5k
    Vnl N002 LOPN 0
    Fnl 3 LOPN Vnl 1
    Dsw N001 N002 DSW
    .model DSW D Is=1e-4
    .model VBUNOR D IS=330E-21 N=1.5 XTI=3 EG=1.52 BV=10.38 IBV=100u
    + CJO=60p VJ=.75 M=.3333 FC=.5 TT=20n
    .model VBUNORC D IS=330E-21 N=1.5 XTI=3 EG=1.52 BV=10.38 IBV=100u
    + CJO=0 VJ=.75 M=.3333 FC=.5 TT=0
    .ends vbu

    .subckt pdnoc LOPP LOPN AN CA
    D1 AN CA PDC
    G1 CA AN LOPP LOPN 0.0020
    V1 LOPN AN 0
    .model PDC D RS=1.0E-3 CJO=0p M=0.333 VJ=0.75 ISR=100.0E-12 BV=100 TT=5E-9
    .ends pdnoc

    .subckt tia in out agnd
    G2 agnd out agnd in 0.1
    R1 N001 in 25K
    C1 out in 2p
    D1 out in D
    R2 out N001 25K
    C2 N002 agnd 1p
    R3 N002 N001 20k
    .ends tia

    .model D D
    .model NPN NPN
    .model PNP PNP
    .model NMOS NMOS
    .model PMOS PMOS
  2. #2
    2013/09/04
    17
    0

    پاسخ : اضافه کردن قطعه در کتابخانه فقط با داشتن مدل SPICE

    سلام
    من هم همین مشکل را دارم مدل قطعه رو از سایت آنالوگ دیوایسز دانلود کردم اما نمیدونم چه جوری به اسپایس اضافه کنم لطفا کمک کنید.
  3. #3
    2009/10/10
    244
    4

    پاسخ : اضافه کردن قطعه در کتابخانه فقط با داش

    من هم مدتی این مشکل رو داشتم. در این pdf این مساله به طور کامل و مرحله به مرحله توضیح داده شده

    Using Texas Instruments Spice Models in PSpice
    www.ti.com/lit/an/sloa070/sloa070.pdf

    پی نوشت: سایت ti اجازه دسترسی از ایران رو نمیده و باید از فیلتر استفاده کنید
    پی نوشت : پلودش کردم
    http://s4.picofile.com/file/8185009634/Using_Texas_Instruments_Spice_Models_in_PSpice_1_. pdf.html
    افتادگی آموز اگر طالب فیضی هرگز نخورد آب زمینی که بلند است
نمایش نتایج: از 1 به 3 از 3

موضوعات مشابه

  1. پاسخ: 1
    آخرين نوشته: 2016/02/04, 18:18
  2. مشکل در اضافه کردن قطعه به کتابخانه !!!
    توسط sma در انجمن نرم افزار Protel
    پاسخ: 2
    آخرين نوشته: 2015/05/11, 09:36
  3. اضافه کردن یک ماژول به یک کتابخانه
    توسط MNR85 در انجمن نرم افزار Protel
    پاسخ: 3
    آخرين نوشته: 2015/03/16, 10:23
  4. اضافه کردن یک قطعه جدید به Pspice
    توسط fered6360 در انجمن آموزش نرم افزارهاي آناليز و شبيه ساز
    پاسخ: 0
    آخرين نوشته: 2013/07/31, 03:19
  5. نبود قطعه در نرم افزار و چگونگی اضافه کردن ان
    توسط masoudkhan در انجمن نرم افزار Proteus
    پاسخ: 2
    آخرين نوشته: 2012/03/25, 18:57

کلمات کلیدی این موضوع

علاقه مندي ها (Bookmarks)

علاقه مندي ها (Bookmarks)

مجوز های ارسال و ویرایش

  • شما نمیتوانید موضوع جدیدی ارسال کنید
  • شما امکان ارسال پاسخ را ندارید
  • شما نمیتوانید فایل پیوست کنید.
  • شما نمیتوانید پست های خود را ویرایش کنید
  •